Solidity Cheatcodes

Каждая Virtual Environment предоставляет прекомпайл-контракт по адресу 0xc100000000000000000000000000000000000000. Вызов функций этого прекомпайла изнутри транзакции позволяет вашим контрактам напрямую манипулировать состоянием on-chain (слотами хранилища, ETH-балансами, балансами токенов ERC-20, nonce и логами событий) без имперсонации аккаунтов и деплоя вспомогательных прокси. Эти чит-коды дополняют методы Admin RPC. Методы Admin RPC манипулируют состоянием извне транзакции (через JSON-RPC). Прекомпайл манипулирует состоянием изнутри транзакции (через Solidity-вызов). Используйте прекомпайл, когда ваш сетап должен оставаться атомарным, быть воспроизводимым по хешу транзакции или выполняться в цикле по многим слотам.

Интерфейс

Добавьте этот файл в ваш проект как IVnetPrecompile.sol:

IVnetPrecompile.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IVnetPrecompile {
    function setStorageAt(address target, bytes32 slot, bytes32 value) external returns (bool);
    function setBalance(address[] calldata addresses, uint256 balance) external returns (bool);
    function getStorageAt(address target, bytes32 slot) external view returns (bytes32);
    function addBalance(address[] calldata addresses, uint256 amount) external returns (bool);
    function setNonce(address target, uint256 value) external returns (bool);
    function setErc20Balance(address target, address[] calldata addresses, uint256 amount) external returns (bool);
    function addErc20Balance(address target, address[] calldata addresses, uint256 amount) external returns (bool);
    function setMaxErc20Balance(address target, address account) external returns (bool);

    function emitEvent(address target, bytes calldata data) external returns (bool);
    function emitEvent(address target, bytes32 topic1) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes calldata data) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes32 topic2) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes32 topic2, bytes calldata data) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes32 topic2, bytes32 topic3) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes32 topic2, bytes32 topic3, bytes calldata data) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes32 topic2, bytes32 topic3, bytes32 topic4) external returns (bool);
    function emitEvent(address target, bytes32 topic1, bytes32 topic2, bytes32 topic3, bytes32 topic4, bytes calldata data) external returns (bool);

    event SetStorageAtEvent(address target, bytes32 slot, bytes32 value);
    event SetBalanceEvent(address[] addresses, uint256 balance);
    event AddBalanceEvent(address[] addresses, uint256 amount);
    event SetNonceEvent(address target, uint256 value);
    event SetErc20BalanceEvent(address target, address[] addresses, uint256 amount);
    event AddErc20BalanceEvent(address target, address[] addresses, uint256 amount);
    event SetMaxErc20BalanceEvent(address target, address account);
}

Ссылайтесь на него в вашем контракте по фиксированному адресу:

IVnetPrecompile constant VNET = IVnetPrecompile(0xc100000000000000000000000000000000000000);

Функции

Хранилище

Функция	Параметры	Возвращает	Описание
`setStorageAt`	`address target`, `bytes32 slot`, `bytes32 value`	`bool`	Записывает `value` в `slot` на `target`.
`getStorageAt`	`address target`, `bytes32 slot`	`bytes32`	Читает текущее значение `slot` на `target`.

VNET.setStorageAt(tokenContract, balanceSlot, bytes32(uint256(1000e18)));
bytes32 val = VNET.getStorageAt(tokenContract, balanceSlot);

Баланс

Функция	Параметры	Возвращает	Описание
`setBalance`	`address[] addresses`, `uint256 balance`	`bool`	Устанавливает ETH-баланс каждого адреса в `addresses` в точное значение.
`addBalance`	`address[] addresses`, `uint256 amount`	`bool`	Добавляет `amount` к текущему ETH-балансу каждого адреса в `addresses`.

address[] memory accounts = new address[](2);
accounts[0] = alice;
accounts[1] = bob;
VNET.setBalance(accounts, 10 ether);
VNET.addBalance(accounts, 2 ether);

Балансы ERC-20

Функция	Параметры	Возвращает	Описание
`setErc20Balance`	`address target`, `address[] addresses`, `uint256 amount`	`bool`	Устанавливает баланс каждого адреса в `addresses` в `amount` на ERC-20 токене по адресу `target`.
`addErc20Balance`	`address target`, `address[] addresses`, `uint256 amount`	`bool`	Добавляет `amount` к текущему балансу токена каждого адреса в `addresses`.
`setMaxErc20Balance`	`address target`, `address account`	`bool`	Устанавливает баланс токена для `account` в максимальное значение (`2^256 - 1`).

Прекомпайл находит слот хранилища баланса токена автоматически, поэтому указывать слот не требуется. Стандартные раскладки mapping разрешаются напрямую и кэшируются после первого держателя; нестандартные раскладки обнаруживаются путём зондирования выполнения balanceOf токена.

address[] memory holders = new address[](2);
holders[0] = alice;
holders[1] = bob;
VNET.setErc20Balance(USDC, holders, 1_000_000e6);
VNET.addErc20Balance(USDC, holders, 500e6);
VNET.setMaxErc20Balance(USDC, alice);

Токены, которые упаковывают дополнительные флаги в слот хранилища баланса, отражают это в balanceOf. Например, USDC резервирует старший бит слота, поэтому после setMaxErc20Balance его balanceOf возвращает 2^255 - 1.

Nonce

Функция	Параметры	Возвращает	Описание
`setNonce`	`address target`, `uint256 value`	`bool`	Задаёт счётчик транзакций для `target`.

VNET.setNonce(account, 42);

События

emitEvent эмитирует лог, у которого поле address — это target, а не вызывающий контракт. Нижестоящие потребители (индексеры, subgraphs, вебхуки) считают лог реальной эмиссией от target. Девять перегрузок покрывают от нуля до четырёх индексируемых топиков с необязательным неиндексируемым data-payload:

Перегрузка	Топики	Данные
`emitEvent(target, data)`	0	✓
`emitEvent(target, t1)`	1	,
`emitEvent(target, t1, data)`	1	✓
`emitEvent(target, t1, t2)`	2	,
`emitEvent(target, t1, t2, data)`	2	✓
`emitEvent(target, t1, t2, t3)`	3	,
`emitEvent(target, t1, t2, t3, data)`	3	✓
`emitEvent(target, t1, t2, t3, t4)`	4	,
`emitEvent(target, t1, t2, t3, t4, data)`	4	✓

topic1 обычно равен keccak256("EventName(type,type,...)"). Пример, подделываем Transfer для USDC:

VNET.emitEvent(
    USDC,
    keccak256("Transfer(address,address,uint256)"),
    bytes32(uint256(uint160(from))),
    bytes32(uint256(uint160(to))),
    abi.encode(amount)
);

События чит-кодов

Каждый чит-код, изменяющий состояние, эмитирует соответствующее событие с адреса прекомпайла (0xc100000000000000000000000000000000000000):

Чит-код	Событие
`setStorageAt`	`SetStorageAtEvent(address target, bytes32 slot, bytes32 value)`
`setBalance`	`SetBalanceEvent(address[] addresses, uint256 balance)`
`addBalance`	`AddBalanceEvent(address[] addresses, uint256 amount)`
`setNonce`	`SetNonceEvent(address target, uint256 value)`
`setErc20Balance`	`SetErc20BalanceEvent(address target, address[] addresses, uint256 amount)`
`addErc20Balance`	`AddErc20BalanceEvent(address target, address[] addresses, uint256 amount)`
`setMaxErc20Balance`	`SetMaxErc20BalanceEvent(address target, address account)`

При проверке чека транзакции на предмет лога, подделанного через emitEvent, фильтруйте logs[] по целевому адресу, чтобы игнорировать собственные записи прекомпайла.

Известные ограничения

Virtual Environments на основе Base. Solidity-чит-коды недоступны на Base.
Virtual Environments на основе Arbitrum. Вызовы чит-кодов через eth_call не работают из-за внутренних особенностей Arbitrum. Транзакции, оценка газа и симуляции работают как ожидается.

См. также

Admin RPC — эквивалентные JSON-RPC методы для манипуляции состоянием извне транзакции.
Туториал по чит-кодам в Foundry — сквозное прохождение с деплоем переиспользуемой песочницы чит-кодов.

Getting Started

Simulator

Console

Monitor

Node RPC

Account & Settings

Solidity Cheatcodes

Интерфейс

Функции

Хранилище

Баланс

Балансы ERC-20

Nonce

События

События чит-кодов

Известные ограничения

См. также

​Интерфейс

​Функции

​Хранилище

​Баланс

​Балансы ERC-20

​Nonce

​События

​События чит-кодов

​Известные ограничения

​См. также

Интерфейс

Функции

Хранилище

Баланс

Балансы ERC-20

Nonce

События

События чит-кодов

Известные ограничения

См. также